Libraries.Robots.Lego.InfraredSensor

The InfraredSensor class is an object representation of the LEGO Mindstorms EV3 Infrared Sensor. It is used to measure distance between the robot and other physical objects. The range at which this sensor works is from around 5 to 40 centimeters. Additionally, the EV3 remote, also called a beacon, interacts with the robot through this sensor.

Example Code

use Libraries.Robots.Lego.InfraredSensor
use Libraries.Robots.Lego.Motor
use Libraries.Robots.Lego.Sound
use Libraries.Robots.Lego.Screen

class Main
    action Main
        InfraredSensor infraredSensor
        Motor motor
        Sound sound
        Screen screen
        
        integer command = 0
        infraredSensor:SetPort(infraredSensor:PORT_4)   //tells the program that there is an infrared sensor connected to port 4 of the robot
        repeat while true
            if infraredSensor:GetDistance() < 25
                screen:Output("Object nearby.", 0)
                sound:Buzz()
            else
                screen:Clear()
                command = infraredSensor:GetRemoteCommand(infraredSensor:CHANNEL_1)  //determines what button was pressed on the EV3 remote over channel 1
                if command = 1                    //forward
                    motor:SetSpeed("B", 480)
                    motor:SetSpeed("C", 480)
                    motor:RotateForward("B")
                    motor:RotateForward("C")
                elseif command = 2                //backward
                    motor:SetSpeed("B", 480)
                    motor:SetSpeed("C", 480)
                    motor:RotateBackward("B")
                    motor:RotateBackward("C")
                elseif command = 3                //right
                    motor:SetSpeed("B", 480)
                    motor:SetSpeed("C", 480)
                    motor:Stop("B")
                    motor:RotateForward("C")
                elseif command = 4                //left
                    motor:SetSpeed("B", 480)
                    motor:SetSpeed("C", 480)
                    motor:Stop("C")
                    motor:RotateForward("B")
                else
                    motor:Stop("B")
                    motor:Stop("C")
                end
            end
        end
    end
end

This action compares two object hash codes and returns an integer. The result is larger if this hash code is larger than the object passed as a parameter, smaller, or equal. In this case, -1 means smaller, 0 means equal, and 1 means larger. This action was changed in Quorum 7 to return an integer, instead of a CompareResult object, because the previous implementation was causing efficiency issues.

Example Code

Object o
        Object t
        integer result = o:Compare(t) //1 (larger), 0 (equal), or -1 (smaller)

This action determines if two objects are equal based on their hash code values.

Example Code

use Libraries.Language.Object
        use Libraries.Language.Types.Text
        Object o
        Text t
        boolean result = o:Equals(t)

This action uses the infrared sensor to measure the distance between it and a physical object directly ahead of it. The reliable range for measuring distance is up to around 50 centimeters.

Example Code

use Libraries.Robots.Lego.InfraredSensor
    use Libraries.Robots.Lego.Motor
    use Libraries.Robots.Lego.Sound
    
    InfraredSensor infraredSensor
    Motor motor
    Sound sound
    
    infraredSensor:SetPort(infraredSensor:PORT_3)   //tells the program that the infrared sensor is plugged into port 3 of the robot
    motor:RotateForward("B")
    motor:RotateForward("C")
    repeat until infraredSensor:GetDistance() < 40  //the robot moves forward until getting close to an object
    end
    sound:BeepTwice()

This action gets the hash code for an object.

Example Code

Object o
        integer hash = o:GetHashCode()

This action retrieves a command, or button press, from an EV3 remote.

Example Code

use Libraries.Robots.Lego.InfraredSensor
    use Libraries.Robots.Lego.Sound

    InfraredSensor infraredSensor
    Sound sound

    infraredSensor:SetPort(infraredSensor:PORT_4)
    integer command = 0
    repeat while true
        command = infraredSensor:GetRemoteCommand(infraredSensor:CHANNEL_1)
        if command = 1              //top left remote button
            sound:PlayTone(200, 20)
        elseif command = 2          //bottom left remote button
            sound:PlayTone(400, 20)
        elseif command = 3          //top right remote button
            sound:PlayTone(800, 20)
        elseif command = 4          //bottom right remote button
            sound:PlayTone(1600, 20)
        end
    end

This action is used to find the direction of an EV3 remote with respect to the infrared sensor.

Example Code

use Libraries.Robots.Lego.InfraredSensor
    use Libraries.Robots.Lego.Motor
    
    InfraredSensor infraredSensor
    Motor motor

    infraredSensor:SetPort(infraredSensor:PORT_4)
    motor:SetSpeed("B", 720)    //this motor should move the right side of the robot
    motor:SetSpeed("C", 720)    //this motor should move the left side of the robot

    integer direction = 0
    repeat while true
        direction = infraredSensor:GetRemoteDirection(infraredSensor:CHANNEL_1) //tells the program to interact with a remote using channel 1
        if direction > 0            //remote is on the right side of the sensor
            motor:RotateForward("C")
            motor:Stop("B")
        elseif direction < 0        //remote is on the left side of the sensor
            motor:RotateForward("B")
            motor:Stop("C")
        elseif infraredSensor:GetRemoteDistance(1) < 100   //remote straight ahead and remote still in range of the sensor
            output infraredSensor:GetRemoteDistance(1)
            motor:RotateForward("B")
            motor:RotateForward("C")
        else                        //found the remote
            motor:Stop("B")
            motor:Stop("C")
        end
    end

This action is used to find the distance of an EV3 remote with respect to the infrared sensor.

Example Code

use Libraries.Robots.Lego.InfraredSensor
    use Libraries.Robots.Lego.Sound

    InfraredSensor infraredSensor
    Sound sound
    
    infraredSensor:SetPort(infraredSensor:PORT_4)
    repeat while true
        if infraredSensor:GetRemoteDistance(1) <= 20
            sound:PlayTone(1100, 20)
        elseif infraredSensor:GetRemoteDistance(1) <= 40
            sound:PlayTone(900, 20)
        elseif infraredSensor:GetRemoteDistance(1) <= 60
            sound:PlayTone(700, 20)
        elseif infraredSensor:GetRemoteDistance(1) <= 80
            sound:PlayTone(500, 20)
        elseif infraredSensor:GetRemoteDistance(1) <= 100
            sound:PlayTone(300, 20)
        else
            sound:PlayTone(20, 20)
        end
    end

This action lets the program know which port on the robot that the infrared sensor being used is plugged into. As such, this action must be called before any other action in the InfraredSensor class will work.

Example Code

use Libraries.Robots.Lego.InfraredSensor

    InfraredSensor infraredSensor1
    InfraredSensor infraredSensor2
    InfraredSensor infraredSensor3
    
    infraredSensor1:SetPort(1)                      //we can have multiple infrared sensors plugged into the robot at once
    infraredSensor2:SetPort(2)                      //after setting the ports, we can now use any other action in the ColorSensor class
    infraredSensor3:SetPort(infraredSensor3:PORT_3) //we can use a class constant to designate a port, as well